Warning, /DQM/CSCMonitorModule/data/emuBooking2RenderPlugin.xsl is written in an unsupported language. File is not indexed.
0001 <?xml version="1.0" encoding="UTF-8"?>
0002
0003 <xsl:stylesheet version="1.0"
0004 xmlns:emu="http://www.phys.ufl.edu/cms/emu/dqm"
0005 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
0006 xmlns:fn="http://www.w3.org/2005/02/xpath-functions">
0007
0008 <xsl:output method="text" omit-xml-declaration="yes" indent="no"/>
0009 <xsl:strip-space elements="*"/>
0010
0011 <xsl:template match="/">
0012
0013 <xsl:text>
0014
0015 // ============== Start generated from emuDQMBooking.xml by emuBooking2RenderPlugin.xsl ==================
0016
0017 </xsl:text>
0018
0019 <xsl:apply-templates select="/emu:Booking/emu:Histogram" mode="frame" />
0020
0021 <xsl:text>
0022 // ============== End generated from emuDQMBooking.xml by emuBooking2RenderPlugin.xsl ==================
0023
0024 </xsl:text>
0025
0026 </xsl:template>
0027
0028 <xsl:template match="emu:Histogram" mode="frame">
0029
0030 <xsl:text>if(reMatch(".*/</xsl:text>
0031 <xsl:value-of select="emu:Name"/>
0032 <xsl:text>$", o.name)) {
0033 </xsl:text>
0034
0035 <xsl:variable name="def" select="@ref" />
0036
0037 <xsl:if test="$def != ''">
0038 <xsl:text> /** Applying definition [</xsl:text>
0039 <xsl:value-of select="$def"/>
0040 <xsl:text>] **/
0041 </xsl:text>
0042 <xsl:apply-templates select="/emu:Booking/emu:Definition[@id = $def]" mode="definition" />
0043 </xsl:if>
0044
0045 <xsl:text> /** Applying histogram **/
0046 </xsl:text>
0047 <xsl:apply-templates select="." mode="definition" />
0048
0049 <xsl:text> return;
0050 }
0051 </xsl:text>
0052 </xsl:template>
0053
0054 <xsl:template match="emu:Histogram|emu:Definition" mode="definition">
0055
0056 <xsl:apply-templates select="emu:SetLeftMargin"/>
0057 <xsl:apply-templates select="emu:SetRightMargin"/>
0058 <xsl:apply-templates select="emu:SetStats"/>
0059 <xsl:apply-templates select="emu:SetOptStat"/>
0060 <xsl:apply-templates select="emu:SetOption"/>
0061 <xsl:apply-templates select="emu:SetGridx[1]"/>
0062 <xsl:apply-templates select="emu:SetGridy[1]"/>
0063 <xsl:if test="emu:SetLogx = 1 or emu:SetLogy = 1 or emu:SetLogz = 1">
0064 <xsl:text> if(obj->GetMinimum() == obj->GetMaximum()) {
0065 obj->SetMaximum(obj->GetMinimum() + 0.01);
0066 }
0067 </xsl:text>
0068 </xsl:if>
0069 <xsl:apply-templates select="emu:SetLogx[1]"/>
0070 <xsl:apply-templates select="emu:SetLogy[1]"/>
0071 <xsl:apply-templates select="emu:SetLogz[1]"/>
0072
0073 </xsl:template>
0074
0075 <xsl:template match="emu:SetLeftMargin|emu:SetRightMargin">
0076 <xsl:text> gPad-></xsl:text>
0077 <xsl:value-of select="name()"/>
0078 <xsl:text>(</xsl:text>
0079 <xsl:value-of select="."/>
0080 <xsl:text>);
0081 </xsl:text>
0082 </xsl:template>
0083
0084 <xsl:template match="emu:SetRightMargin">
0085 <xsl:text> gPad->SetRightMargin(</xsl:text>
0086 <xsl:value-of select="."/>
0087 <xsl:text>);
0088 </xsl:text>
0089 </xsl:template>
0090
0091 <xsl:template match="emu:SetStats">
0092 <xsl:text> obj->SetStats(</xsl:text>
0093 <xsl:choose>
0094 <xsl:when test=". = 1"><xsl:text>true</xsl:text></xsl:when>
0095 <xsl:when test=". = 0"><xsl:text>false</xsl:text></xsl:when>
0096 </xsl:choose>
0097 <xsl:text>);
0098 </xsl:text>
0099 </xsl:template>
0100
0101 <xsl:template match="emu:SetOptStat">
0102 <xsl:text> gStyle->SetOptStat("</xsl:text>
0103 <xsl:value-of select="."/>
0104 <xsl:text>");
0105 </xsl:text>
0106 </xsl:template>
0107
0108 <xsl:template match="emu:SetOption">
0109 <xsl:text> obj->SetOption("</xsl:text>
0110 <xsl:value-of select="."/>
0111 <xsl:text>");
0112 </xsl:text>
0113 </xsl:template>
0114
0115 <xsl:template match="emu:SetGridx[1]|emu:SetGridy[1]|emu:SetLogx[1]|emu:SetLogy[1]|emu:SetLogz[1]">
0116 <xsl:text> gPad-></xsl:text>
0117 <xsl:value-of select="name()"/>
0118 <xsl:text>();
0119 </xsl:text>
0120 </xsl:template>
0121
0122 </xsl:stylesheet>
